This Mathematica file calculates the sources for differential equations necessary for metric components of our black brane solution in AdS4 at first and second order. We reproduce most of the results in hep-th/0802.3224, but notably disagree in our second order source for k. This file uses the Mathematica tensor package RGTC.

Setup and Definitions

<<EDCRGTCcode.m

Print;Unprotect[Print];Print=Null&;

Definitions and Metric Setup

Various defintions to be used later. Some are only now for convenience used to build the form of the metric.

coords = {t, x, y, r};
f = 1 - (((T[t,x,y])^3)/(r^3));
Fr=(1/6) ((Sqrt[3]) π-2 (Sqrt[3]) ArcTan[((1+2 r)/(Sqrt[3]))]-6 Log[r]+3 Log[1+r+(r^2)]);

j1={j1t[t,x,y,r],j1x[t,x,y,r],j1y[t,x,y,r],0};
a1={
{a1tt[t,x,y,r],a1tx[t,x,y,r],a1ty[t,x,y,r],0},
{a1tx[t,x,y,r],a1xx[t,x,y,r],a1xy[t,x,y,r],0},
{a1ty[t,x,y,r],a1xy[t,x,y,r],a1yy[t,x,y,r],0},
{0,0,0,0}} ;
j2={j2t[t,x,y,r],j2x[t,x,y,r],j2y[t,x,y,r],0};
a2={
{a2tt[t,x,y,r],a2tx[t,x,y,r],a2ty[t,x,y,r],0},
{a2tx[t,x,y,r],a2xx[t,x,y,r],a2xy[t,x,y,r],0},
{a2ty[t,x,y,r],a2xy[t,x,y,r],a2yy[t,x,y,r],0},
{0,0,0,0}} ;

Ud={-ut[t,x,y],ux[t,x,y],uy[t,x,y],0};
UU={ut[t,x,y],ux[t,x,y],uy[t,x,y],0};
dr={0,0,0,1};
n={{-1,0,0,0},{0,1,0,0},{0,0,1,0},{0,0,0,0}};
g0=-( Outer[Times,Ud,dr]+Outer[Times,dr,Ud]) - (r^2) f Outer[Times, Ud, Ud]+ (r^2) (n+Outer[Times,Ud,Ud]);
g1k=k1[t,x,y,r]/(r^2) Outer[Times,Ud, Ud];
g1h=-h1[t,x,y,r]( Outer[Times,Ud,dr]+Outer[Times,dr,Ud])-(r^2) h1[t,x,y,r] (n+Outer[Times,Ud,Ud]);
g1j=-1/r (Outer[Times,j1,Ud]+Outer[Times,Ud,j1]);
g1a=(r^2) a1;
g2k=k2[t,x,y,r]/(r^2) Outer[Times,Ud, Ud];
g2h=-h2[t,x,y,r]( Outer[Times,Ud,dr]+Outer[Times,dr,Ud])-(r^2) h2[t,x,y,r] (n+Outer[Times,Ud,Ud]);
g2j=-1/r (Outer[Times,j2,Ud]+Outer[Times,Ud,j2]);
g2a=(r^2) a2;
(*Construct pieces of the metric*)

Replacements

βrep replaces our velocity variables u with the more convenient β. localrep replaces a general velocity flow with a locally co-moving frame. rfunctrep is purely cosmetic.

βrep={ut->Function[{t,x,y},(1/(Sqrt[1-((βx[t,x,y])^2)-((βy[t,x,y])^2)]))],ux->Function[{t,x,y},((βx[t,x,y])/(Sqrt[1-((βx[t,x,y])^2)-((βy[t,x,y])^2)]))],uy->Function[{t,x,y},((βy[t,x,y])/(Sqrt[1-((βx[t,x,y])^2)-((βy[t,x,y])^2)]))],T->Function[{t,x,y},(1/(b[t,x,y]))]};
localrep={ut->Function[{t,x,y}, 1],ux->Function[{t,x,y}, 0],uy->Function[{t,x,y}, 0]};
rfunctrep={
h1->Function[{t,x,y,r},h1[r]],
k1->Function[{t,x,y,r},k1[r]],
j1t->Function[{t,x,y,r},j1t[r]],
j1x->Function[{t,x,y,r},j1x[r]],
j1y->Function[{t,x,y,r},j1y[r]],
a1tt->Function[{t,x,y,r},a1tt[r]],
a1tx->Function[{t,x,y,r},a1tx[r]],
a1ty->Function[{t,x,y,r},a1ty[r]],
a1xx->Function[{t,x,y,r},a1xx[r]],
a1xy->Function[{t,x,y,r},a1xy[r]],
a1yy->Function[{t,x,y,r},a1yy[r]],
h2->Function[{t,x,y,r},h2[r]],
k2->Function[{t,x,y,r},k2[r]],
j2t->Function[{t,x,y,r},j2t[r]],
j2x->Function[{t,x,y,r},j2x[r]],
j2y->Function[{t,x,y,r},j2y[r]],
a2tt->Function[{t,x,y,r},a2tt[r]],
a2tx->Function[{t,x,y,r},a2tx[r]],
a2ty->Function[{t,x,y,r},a2ty[r]],
a2xx->Function[{t,x,y,r},a2xx[r]],
a2xy->Function[{t,x,y,r},a2xy[r]],
a2yy->Function[{t,x,y,r},a2yy[r]]
};

First Order Sources

Scalar -- h

Do the calculation locally at the point t=x=y=0

b[0,0,0]=1;
βx[0,0,0]=0;
βy[0,0,0]=0;
g0o1=(g0+((O[ϵ])^2))/.βrep/.{t->ϵ t, x->ϵ x,y->ϵ y};

Construct the Einstein tensor, using only scalar corrections.

g1hko1 = ϵ(g1h+g1k)/.βrep/.{t->ϵ t, x->ϵ x,y->ϵ y};
RGtensors[g0o1+g1hko1,coords, {0,0}];
Wdd=Rdd+3gdd/.{t->0,x->0,y->0};

Find the equation for our h term and see what our source is.

hEq=Normal[Wdd[[4,4]]]/.ϵ->1/.rfunctrep//FullSimplify;
hSource=-hEq/.h1->Function[r,0]//FullSimplify

Scalar -- k

Find the equation for our k term and see what our source is

hkEq=Normal[(r^4) (f/.βrep/.{t->ϵ t, x->ϵ x,y->ϵ y}) Wdd[[4,4]]-Wdd[[2,2]]-Wdd[[3,3]]]/.ϵ->1/.rfunctrep//Simplify//FullSimplify;
hkSource = -hkEq/.h1->Function[r,0]/.k1->Function[r,0]//FullSimplify

Vector -- j

Construct the Einstein tensor, using vector corrections.

g1jo1 = (ϵ g1j + ((O[ϵ])^2))/.βrep/.{t->ϵ t, x->ϵ x,y->ϵ y};
RGtensors[g0o1+g1jo1,coords, {0,0}];
Wdd=Rdd+3gdd/.{t->0,x->0,y->0};

Find the equation for j and see what our source is. We are checking the jx component.

jEq= Normal[Wdd[[2,4]]]/.ϵ->1/.rfunctrep//Simplify;
jSource=-jEq/.j1x->Function[r,0]//FullSimplify

Tensor -- α

Construct the Einstein tensor, using tensor corrections.

g1ao1=(ϵ g1a+((O[ϵ])^2))/.βrep/.{t->ϵ t, x->ϵ x,y->ϵ y};
RGtensors[g0o1+g1ao1,coords, {0,0}];
Wdd=Rdd+3gdd/.{t->0,x->0,y->0};

Find the equation for α and see what our source is. We are checking the αxy component.

aEq=Normal[Wdd[[2,3]]]/.ϵ->1/.rfunctrep//Simplify;
aSource=-aEq/.a1xy->Function[r,0]//FullSimplify

Covariantize

To generalize to a non-local frame, we would like to “covariantize” our solution. We will then take the solution of the differential equations given in hep-th/0802.3224 and explicitly check that it solves the first order solution in arbitrary frame.

RGtensors[{{-1,0,0,0},{0,1,0,0},{0,0,1,0},{0,0,0,1}},coords];
h1cov=0;
k1cov=(r^3) covDiv[UU,{1}];
j1cov=UU.Transpose[covD[Ud]];
DUU=Transpose[FullSimplify[Raise[covD[UU, {1}],2]]];
PUU=(n+Outer[Times,UU,UU]);
PUd=Lower[PUU,2];
Pdd=Lower[PUd,1];
ΠUUdd=(1/2)(Transpose[Outer[Times,PUd,PUd],{1,3,2,4}]+Transpose[Transpose[Outer[Times,PUd,PUd],{1,3,2,4}],{1,2,4,3}]-Outer[Times,PUU,Pdd]);
σUU=Contract[Outer[Times,ΠUUdd,DUU],{3,5},{4,6}];
σdd=gdd.σUU.gdd;
a1cov=2/T[t,x,y] FF[r/T[t,x,y]] σdd;

solh1cov=h1->Function[{t,x,y,r},h1cov];
solk1cov=k1->Function[{t,x,y,r}, k1cov/.{t->t,x->x,y->y}];
solj1cov={
j1t->Function[{t,x,y,r},(r^2) j1cov[[1]]/.{t->t,x->x,y->y}],
j1x->Function[{t,x,y,r}, (r^2) j1cov[[2]]/.{t->t,x->x,y->y}],
j1y->Function[{t,x,y,r}, (r^2) j1cov[[3]]/.{t->t,x->x,y->y}]
};
sola1cov={
a1tt->Function[{t,x,y,r},a1cov[[1,1]]/.{t->t,x->x,y->y}],
a1tx->Function[{t,x,y,r},a1cov[[1,2]]/.{t->t,x->x,y->y}],
a1ty->Function[{t,x,y,r},a1cov[[1,3]]/.{t->t,x->x,y->y}],
a1xx->Function[{t,x,y,r},a1cov[[2,2]]/.{t->t,x->x,y->y}],
a1xy->Function[{t,x,y,r},a1cov[[2,3]]/.{t->t,x->x,y->y}],
a1yy->Function[{t,x,y,r},a1cov[[3,3]]/.{t->t,x->x,y->y}]
};

b[0,0,0]=1;
βx[0,0,0]=0;
βy[0,0,0]=0;
g0o2=(g0+((O[ϵ])^2))/.βrep/.{t->ϵ t, x->ϵ x,y->ϵ y};
g1o2=ϵ (g1k+g1h+g1j+g1a)+((O[ϵ])^2)/.solk1cov/.solh1cov/.solj1cov/.sola1cov/.βrep/.{t->ϵ t, x->ϵ x,y->ϵ y};

RGtensors[g0o2+g1o2, coords,{0,0}];
Wdd=Rdd+3gdd;

Hydro Solution

Before we can plug into the EFE however, we need to make sure we solve our hydro equations. These equations come from Wdd[1,4] components. We will simply take the hydro results as a given, and show that if they are satisfied, the Einstein tensor vanishes at first order.

RGtensors[{{-1,0,0,0},{0,1,0,0},{0,0,1,0},{0,0,0,1}},coords];
TUU=((T[t,x,y])^3)*({{-1,0,0,0},{0,1,0,0},{0,0,1,0},{0,0,0,0}}+3Outer[Times,UU, UU]);
hydro01=(covDiv[TUU,{1,{2}}]/.βrep//Simplify)/.{t->0,x->0,y->0}/.{b[0,0,0]->1,ut[0,0,0]->1,ux[0,0,0]->0,uy[0,0,0]->0,βx[0,0,0]->0,βy[0,0,0]->0}//Simplify;
hydro01rep=Solve[Map[#==0&, hydro01],{ Derivative[1,0,0][b][0,0,0],Derivative[0,1,0][b][0,0,0],Derivative[0,0,1][b][0,0,0]}][[1]];

Check that our first order solution is valid

Our first order solution works

Wdd/.FF->Function[r,Fr/.r->r]/.hydro01rep//Simplify//MatrixForm

Second Order Sources

Definitions

Define various scalar, vector, and tensor terms to be used later.

S3=Derivative[1,0,1][βy][0,0,0]+Derivative[1,1,0][βx][0,0,0];
S4 = ((Derivative[1,0,0][βx][0,0,0])^2)+((Derivative[1,0,0][βy][0,0,0])^2);
S5 = (((Derivative[0,0,1][βy][0,0,0]+Derivative[0,1,0][βx][0,0,0]))^2);
S6 = (((-Derivative[0,0,1][βx][0,0,0]+Derivative[0,1,0][βy][0,0,0]))^2);
S7 = (1/2) (((Derivative[0,0,1][βx][0,0,0])^2)+((Derivative[0,0,1][βy][0,0,0])^2)-2 Derivative[0,0,1][βy][0,0,0] Derivative[0,1,0][βx][0,0,0]+((Derivative[0,1,0][βx][0,0,0])^2)+2 Derivative[0,0,1][βx][0,0,0] Derivative[0,1,0][βy][0,0,0]+((Derivative[0,1,0][βy][0,0,0])^2));

V3x = Derivative[0,1,1][βy][0,0,0]+Derivative[0,2,0][βx][0,0,0];
V4x = Derivative[0,0,2][βx][0,0,0]+Derivative[0,2,0][βx][0,0,0];
V5x = Derivative[0,0,1][βy][0,0,0] Derivative[1,0,0][βx][0,0,0]+Derivative[0,1,0][βx][0,0,0] Derivative[1,0,0][βx][0,0,0];
V6x = Derivative[0,1,0][βx][0,0,0] Derivative[1,0,0][βx][0,0,0]+Derivative[0,1,0][βy][0,0,0] Derivative[1,0,0][βy][0,0,0];
V7x = Derivative[0,1,0][βx][0,0,0] Derivative[1,0,0][βx][0,0,0]+Derivative[0,0,1][βx][0,0,0] Derivative[1,0,0][βy][0,0,0];
T2xy = (1/2)(Derivative[1,1,0][βy][0,0,0] + Derivative[1,0,1][βx][0,0,0]);
T3xy = Derivative[1,0,0][βx][0,0,0] Derivative[1,0,0][βy][0,0,0];
T4xy = Derivative[0,0,1][βx][0,0,0] Derivative[0,0,1][βy][0,0,0]+Derivative[0,1,0][βx][0,0,0] Derivative[0,1,0][βy][0,0,0];
T5xy = Derivative[0,0,1][βx][0,0,0] Derivative[0,1,0][βx][0,0,0]+Derivative[0,0,1][βy][0,0,0] Derivative[0,1,0][βy][0,0,0];

Scalar -- h

Construct the Einstein tensor locally, using only scalar second-order corrections.

b[0,0,0]=1;
βx[0,0,0]=0;
βy[0,0,0]=0;
g0o2=(g0+((O[ϵ])^3))/.βrep/.{t->ϵ t, x->ϵ x,y->ϵ y};
g1o2=ϵ (g1k+g1h+g1j+g1a)+((O[ϵ])^3)/.solk1cov/.solh1cov/.solj1cov/.sola1cov/.βrep/.{t->ϵ t, x->ϵ x,y->ϵ y};
g2hk=(ϵ^2)(g2h+g2k)+((O[ϵ])^3)/.βrep/.{t->ϵ t, x->ϵ x,y->ϵ y};
RGtensors[g0o2+g1o2+g2hk,coords, {0,0}];
Wdd=Rdd+3gdd/.{t->0,x->0,y->0};

Find the equation for h and find our source

hEq=Normal[Wdd[[4,4]]]/.ϵ->1/.rfunctrep//FullSimplify;
hSource=-hEq/.h2->Function[r,0]//FullSimplify;
hSource = hSource/.FF->Function[r,Fr/.r->r];

Check the source matches what we claim it is

hSource - (((-1)/(2(r^4)))S6 + (((2(1+2r))/((r^2)((((r^2)+r+1))^2)))Fr - ((((r+1))^2)/((r^2)((((r^2)+r+1))^2))))S7)//Simplify

Scalar -- k

Find the equation for h and find our source

hkEq=Normal[(r^4) (f/.βrep/.{t->ϵ t, x->ϵ x,y->ϵ y}) Wdd[[4,4]]-Wdd[[2,2]]-Wdd[[3,3]]]/.ϵ->1/.rfunctrep//Simplify//FullSimplify;
hkSource = -hkEq/.h2->Function[r,0]/.k2->Function[r,0]//FullSimplify;
hkSource = hkSource/.FF->Function[r,Fr/.r->r];

Check the source matches what we claim it is. Note that this is different from the literature.

hkSource - (2 S3 + (1/2) S5 - ((1 + 4 (r^3))/(2 (r^3))) S6 + (((2 (1+r)(1-4(r^3)))/(r(1+r+(r^2)))) Fr + ((-1+2r+4(r^2)+4(r^3))/(r(1+r+(r^2)))))S7)//Simplify

Vector -- j

Construct the Einstein tensor using only vector second-order corrections.

g2jo2=((ϵ^2) g2j+((O[ϵ])^3))/.βrep/.{t->ϵ t, x->ϵ x,y->ϵ y};
RGtensors[g0o2+g1o2+g2jo2,coords, {0,0}];Wdd=Rdd+3gdd/.{t->0,x->0,y->0};

Find the equation for j and find our source. We are computing the jx source.

jEq= Normal[Wdd[[2,4]]]/.ϵ->1/.rfunctrep//Simplify;
jSource=-jEq/.j2x->Function[r,0]//FullSimplify;
jSource=jSource/.FF->Function[r,Fr/.r->r]//Simplify;
jSource = jSource/.hydro01rep//Simplify;

Check the source matches our claim.

jSource - ((1/(2(r^2)))V3x - (1/(2(r^2)(1+r+(r^2))))V4x - (((r^2)+r-1)/(2(r^2)((r^2)+r+1)))(V6x-V5x))//Simplify

Tensor -- α

Construct the Einstein tensor using only tensor second-order corrections.

g2ao2=((ϵ^2) g2a+((O[ϵ])^3))/.βrep/.{t->ϵ t, x->ϵ x,y->ϵ y};
RGtensors[g0o2+g1o2+g2ao2,coords, {0,0}];
Wdd=Rdd+3gdd/.{t->0,x->0,y->0};

Find the equation for α and find our source. We are computing the αxy term.

aEq=Normal[Wdd[[2,3]]]/.ϵ->1/.rfunctrep//Simplify;
aSource=-aEq/.a2xy->Function[r,0]//FullSimplify;
aSource = aSource/.FF->Function[r,Fr/.r->r]//Simplify;
aSource = aSource/.hydro01rep//Simplify;

Check the source matches our claim.

aSource - ((2r Fr - ((2 r (r+1))/((r^2)+r+1)))(T2xy + T3xy) + (((-r)/2)Fr - (1/(2((r^2)+r+1))))T4xy + ((3/2) r Fr - ((2 (r^2) + 2 r -1)/(2((r^2)+r+1))))T5xy)//Simplify